OPTIONS LS=72;
TITLE 'EXAMPLE 16. ONE-WAY FIXED-EFFECTS ANOVA MODEL: VENEER DATA';
DATA VENEER;
N=_N_;
INPUT BRAND $ WEAR @@;
CARDS;
ACME  2.3 ACME  2.1 ACME  2.4 ACME  2.5
CHAMP 2.2 CHAMP 2.3 CHAMP 2.4 CHAMP 2.6
AJAX  2.2 AJAX  2.0 AJAX  1.9 AJAX  2.1
TUFFY 2.4 TUFFY 2.7 TUFFY 2.6 TUFFY 2.7
XTRA  2.3 XTRA  2.5 XTRA  2.3 XTRA  2.4
;
PROC PRINT DATA=VENEER;


/* PROC ANOVA FOR ONE-WAY ANALYSIS */
/* F-TEST FOR ONE-WAY ANOVA        */
PROC ANOVA DATA=VENEER;
CLASS BRAND;
MODEL WEAR=BRAND;


/* MULTIPLE COMPARISONS OF MEAN */
MEANS BRAND/LSD;

/* CONFIDENCE INTERVALS ABOUT THE MEANS */
MEANS BRAND/CLM;


/* USE PROC GLM FOR ONE-WAY ANALYSIS */
/* GIVES ADDITIONAL FLEXIBILITY      */
PROC GLM DATA=VENEER;
CLASS BRAND;
MODEL WEAR=BRAND;


/* PREPLANNED CONTRASTS: F-TEST FOR A HYPOTHESIS ON A LINEAR             */
/* COMBINATION OF PARAMETERS BEING ZERO                                  */
/* FORM IS CONTRAST 'LABEL' EFFECT-NAME EFFECT-COEFFICIENTS WHERE        */
/* ORDERING OF NUMBERS IN EFFECTS-COEFFICIENTS FOLLOWS THE ALPHABETICAL */
/* ORDERING OF LEVELS OF CLASSIFICATION VARIABLE                         */

/* U.S. VS FOREIGN BRAND */
CONTRAST 'US VS FOREIGN ' BRAND .33333 .33333 .33333 -.5 -.5;


/* ALTERNATE (EQUIVALENT0 FORM OF U.S. VS FOREIGN BRAND */
CONTRAST 'US VS FOREIGN' BRAND 2 2 2 -3 -3;


/* COMPARE A-LINE VS C-LINE BRANDS */
CONTRAST 'ALINE VS CLINE' BRAND 1 1 -2 0 0;


/* COMPARE BRANDS WITHIN A-LINE */
CONTRAST 'ACME VS AJAX' BRAND 1 -1 0 0 0;


/* COMPARE THE FOREIGN BRANDS */
CONTRAST 'TUFFY VS XTRA' BRAND 0 0 0 1 -1;


/* TO ILLUSTRATE EFFECT OF THESE BEING ORTHOGONAL CONTRASTS */
CONTRAST 'US VS FOREIGN' BRAND 2 2 2 -3 -3;
CONTRAST 'ALINE VS CLINE' BRAND 1 1 -2 0 0;
CONTRAST 'ACME VS AJAX' BRAND 1 -1 0 0 0;
CONTRAST 'TUFFY VS XTRA' BRAND 0 0 0 1 -1;


/* SIMULTANEOUSLY TEST SEVERAL CONTRASTS      */
/* TEST WHETHER ALL THREE US BRANDS ARE EQUAL */
CONTRAST 'US BRANDS' BRAND 1 -1 0 0 0, BRAND 1 0 -1 0 0;


/* ESTIMATE LINEAR COMBINATIONS OF PARAMETERS */
/* ESTIMATE DIFFERENCE BETWEEN A-LINE BRANDS  */
ESTIMATE 'ACME VS AJAX' BRAND 1 -1 0 0 0;


/* ESTIMATE AVERAGE OF THREE US MEANS */
ESTIMATE 'US AVERAGE' INTERCEPT 3 BRAND 1 1 1 0 0/DIVISOR=3;