OPTIONS LS=72;
TITLE 'EXAMPLE 20. TWO-WAY ANOVA: BATTERY DATA';
DATA BATTERY;
N=_N_;
INPUT PLATE $ TEMP $ LIFE @@;
CARDS;
M1 T1 130  M1 T1 155  M1 T1  74  M1 T1 180
M2 T1 150  M2 T1 188  M2 T1 159  M2 T1 126
M3 T1 138  M3 T1 110  M3 T1 168  M3 T1 160
M1 T2  34  M1 T2  40  M1 T2  80  M1 T2  75
M2 T2 136  M2 T2 122  M2 T2 106  M2 T2 115
M3 T2 174  M3 T2 120  M3 T2 150  M3 T2 139
M1 T3  20  M1 T3  70  M1 T3  82  M1 T3  58
M2 T3  25  M2 T3  70  M2 T3  58  M2 T3  45
M3 T3  96  M3 T3 104  M3 T3  82  M3 T3  60
;
/* ANOVA AND F-TEST                             */
/* MULTIPLE COMPARISONS OF MAIN EFFETS          */
/* USEFUL WHEN INTERACTIONS ARE NOT SIGNIFICANT */
PROC ANOVA DATA=BATTERY;
CLASS PLATE TEMP;
MODEL LIFE=PLATE TEMP PLATE*TEMP;
MEANS PLATE TEMP PLATE*TEMP/DUNCAN;
RUN;

/* MULTIPLE COMPARISONS OF EFFECTS OF FACTOR 1  */
/* AT FIXED LEVELS OF FACTOR 2                  */
/* USEFUL WHEN INTERACTIONS ARE SIGNIFICANT     */
PROC SORT DATA=BATTERY;
BY TEMP;
PROC ANOVA DATA=BATTERY;
BY TEMP;
CLASS PLATE;
MODEL LIFE=PLATE;
MEANS PLATE/DUNCAN;
RUN;

/* SIMPLE EFFECT COMPARISONS                       */
/* COMPARE MEAN OF PLATE1 VS AVERAGE OF PLATE2 AND */
/* PLATE 3 FOR EACH TEMP LEVEL                     */
PROC GLM DATA=BATTERY;
CLASS PLATE TEMP;
MODEL LIFE=PLATE TEMP PLATE*TEMP/SS1 SS2 SS3 SS4 SOLUTION
                                 E E1 E2 E3 E4;
RUN;

/* AT TEMP1 */
ESTIMATE 'P1 VS P2,P3 IN T1' PLATE 1 -.5 -.5
PLATE*TEMP 1 0 0 -.5 0 0 -.5 0 0;

/* AT TEMP2 */
ESTIMATE 'P1 VS P2,P3 IN T2' PLATE 1 -.5 -.5
PLATE*TEMP 0 1 0 0 -.5 0 0 -.5 0;

/* AT TEMP3 */
ESTIMATE 'P1 VS P2,P3 IN T3' PLATE 1 -.5 -.5
PLATE*TEMP 0 0 1 0 0 -.5 0 0 -.5;
RUN;

/* MAIN EFFECTS COMPARISONS */
/* AVERAGED OVER ALL TEMPS  */
ESTIMATE 'P1 VS P2,P3 ON AVG' PLATE 1 -.5 -.5
PLATE*TEMP 2 2 2 -1 -1 -1 -1 -1 -1 /DIVISOR=6;

/* SIMULTANEOUS CONTRASTS                                      */
/* TEST HYPOTHESIS OF NO INTERACTION BETWEEN PLATE1 VS PLATE2, */
/* PLATE3 AND TEMPS                                            */
CONTRAST 'P1 VS P2,P3*TEMPS'
PLATE*TEMP 1 0 -1 -.5 0 .5 -.5 0 .5,
PLATE*TEMP 0 1 -1 0 -.5 .5 0 -.5 .5;
RUN;