OPTIONS LS=72;
TITLE 'EXAMPLE 21. TWO-FACTOR UNBALANCED MODEL: RATIONS DATA';
DATA RATIONS;
N=_N_;
INPUT FEED $ SIRE $ WEIGHT @@;
CARDS;
F1 S1 5   F1 S1 6
F1 S2 2   F1 S2 3   F1 S2 5   F1 S2 6   F1 S2 7
F1 S3 3
F2 S1 2   F2 S1 3
F2 S2 8   F2 S2 8   F2 S2 9
F2 S3 4   F2 S3 4   F2 S3 6   F2 S3 6   F2 S3 7
;
PROC GLM DATA=RATIONS;
CLASS FEED SIRE;
MODEL WEIGHT=FEED SIRE FEED*SIRE/SS1 SS2 SS3 SS4 SOLUTION
                                 E E1 E2 E3 E4;
RUN;

/* RAW MAIN EFFECTS AND INTERACTION MEANS (UNADJUSTED)  */
MEANS FEED SIRE;

/* ADJUSTED MEANS FOR MAIN EFFECTS WITH STANDARD ERRORS */
LSMEANS FEED SIRE/STDERR;

/* MAIN EFFECTS CONTRASTS                        */
/* NOTE THAT 'ALL FEED' IS EQUIVALENT TO         */
/* FEED -1 1 FEED*SIRE 1 1 1 -1 -1 -1 /DIVISOR 3 */
CONTRAST 'ALL FEED' FEED -1 1;
CONTRAST 'ALL SIRE' SIRE 1 0 -1, SIRE 0 1 -1;
CONTRAST 'SIRE1 VS SIRE2, SIRE3' SIRE -1 .5 .5;
CONTRAST 'SIRE2 VS SIRE3' SIRE 0 -1 1;

/* INTERACTION EFFECTS CONTRASTS */
CONTRAST 'FEED*SIRE 2 VS SIRE3' FEED*SIRE 0 1 -1 0 -1 1;
RUN;